引用:

公式名称: 用DMI捕捉暴涨股
适用软件: 分析家
发 表 人: 福如泉涌     
发表日期: 2006-02-19
发表网址: http://www.chcj.net/viewthread.php?tid=390666&highlight=

引用:

用DMI捕捉暴涨股(原创)



为了响应南山版主关于"让我们共同来找指标中的金矿和友谊的金矿．"的号召,也为了报答各位版主和朋友的帮助,我介绍一种捕捉暴涨股的方法,供大家参考.
下面我把原码公布于下:
TR := SUM(MAX(MAX(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(LOW-REF(CLOSE,1))),N);
HD := HIGH-REF(HIGH,1);
LD := REF(LOW,1)-LOW;
DMP:= SUM(IF(HD>0 AND HD>LD,HD,0),N);
DMM:= SUM(IF(LD>0 AND LD>HD,LD,0),N);
PDI: DMP*100/TR;
MDI: DMM*100/TR;
ADX: MA(ABS(MDI-PDI)/(MDI+PDI)*100,M);
ADXR:(ADX+REF(ADX,M))/2;
预警:if(ADX>90 and PDI=0,30,0),coloryellow,linethick2;
买:if(cross(PDI,MDI)  and (C >1.05*ref(C,1) or ref(C,1)>1.05*ref(C,2)) and (V>2*ref(V,1) or ref(V,1)>2*ref(V,2))and ma(V,5)>ma(V,60) ,20,0),colorred,linethick2;
买2:if(cross(PDI,MDI) and count(预警,10)>=1,10,0),colormagenta,linethick3;

发图一张,供参考:

引用:

n: 1  100  7;
m:  1   100   3;

引用:

由原码可知,公式规定,买入条件为:PDI金叉MDI,并且股加在当天或上一日涨幅超过5%.PDI金叉MDI标明有增量资金入场,而涨幅大于5%,则标明主力拉升股价的决心和实力.两个因素相加,短线暴涨也就可以期待了!
短线涨幅的大小还取决于PDI向上攻击的力度,即其上升角度的大小.如果PDI在短时间内(越短越好)由低位一举上穿MDI,ADX,ADXR到达最高值,应毫不犹豫地果断追涨买进,因为一轮短线暴涨行情就此开始了!

最后,需要说明的是,买入后如果股价未能如愿上涨,则应在跌破止损价后果断止损,而不应对其再抱幻想,毕竟资金的安全是第一位的.

[ 本帖最后由 蓝鼠 于 2008-2-28 13:01 编辑 ]

引用:

公式名称: 黑马发现
适用软件: 分析家
发 表 人: 福如泉涌     
发表日期: 2006-11-13
发表网址: http://www.chcj.net/viewthread.php?tid=561868&highlight=

引用:

捕捉大黑马的好指标-----黑马发现



这是我非常喜欢的副图指标,是捕捉黑马的有效工具.具体用法在指标中已有说明,在此不再贅言.

原码如下:

{126    1   1000}

Var3:=EMA(100*(CLOSE-LLV(LOW,100))/(HHV(HIGH,100)-LLV(LOW,100)),5);
Var4:=(CLOSE-LLV(CLOSE,N))/(HHV(CLOSE,N)-LLV(CLOSE,N))*100;
Var5:=EMA(CLOSE,2)-EMA(CLOSE,150);
Var6:=EMA(Var5,100);
Var7:=2*(Var5-Var6);
Var8:=POW(Var7,3)*0.1+POW(Var7,1);
Var9:=SQRT(SQRT(LOW*HIGH*OPEN*CLOSE));
VarA:=EMA(Var9*0.97,3);
VarB:=(HIGH+LOW+CLOSE)/3;
VarC:=(VarB-MA(VarB,14))/(0.015*AVEDEV(VarB,14));
黑马线: IF(YEAR<2008 AND Var7>0.1,Var8,0)*5,STICK ,LINETHICK3 ,COLOR0099CC;
VarD:=LLV(HIGH,240);
VarE:=100*(CLOSE-VarD)/VarD;
VarF:=AMOUNT/VOL;
Var10:=EMA((WINNER(CLOSE*1.1)-WINNER(CLOSE*0.9))*80,5);
Var11:=INDEXC;
Var12:=MA(Var11,5);
Var13:=MA(Var11,20);
Var14:=MA(Var11,30);
Var15:=Var14>Var12*1.08 AND Var13>Var12*1.055;
Var16:=Var12>Var11*1.03 AND Var13>Var11*1.13;
Var17:=Var16;
Var18:=IF(FILTER(Var10<6,5)=1,1,0);
发现: (Var18 AND VarE<-2.5 AND Var3<5 AND Var4=0)*60,STICK, COLORMAGENTA;
Var19:=Var10<6 AND Var17;
黑马: IF(FILTER(Var19,1)=1,1,0)*80,STICK ,  COLORFF6666;
大黑马:if( Var19 AND Var18*80,80,0),LINETHICK2, COLORFF9966;
操盘手: Var4,COLORGRAY;
Var1A:=CROSS(黑马线,2);
Var1B:=CROSS(黑马线,4);
庄拉: IF(FILTER((Var1A OR Var1B) AND Var4<40 AND Var3<40,5)=1,35,0), COLORRED;
Var1C:=(CLOSE-MA(CLOSE,6))/MA(CLOSE,6)*100;
Var1D:=(CLOSE-MA(CLOSE,12))/MA(CLOSE,12)*100;
Var1E:=(CLOSE-MA(CLOSE,24))/MA(CLOSE,24)*100;
Var1F:=REF(CLOSE,1);
Var20:=SMA(MAX(CLOSE-Var1F,0),5,1)/SMA(ABS(CLOSE-Var1F),5,1)*100;
Var21:=(HIGH+LOW+CLOSE)/3;
Var22:=(Var21-MA(Var21,14))/(0.015*AVEDEV(Var21,14));
Var23:(Var1C>=-15.8 AND Var1C<=-12.2 AND Var1D<=-20.8 AND Var1E<=-27.5 AND Var20<=11.7
AND Var22<=-145)*100;
Var24:=Var4;
Var25:=Var4=100;
STICKLINE(Var23>0,90,100,5,0), LINETHICK3 , COLORRED;
DRAWTEXT(Var23>0,90,'发现大黑马加把安全锁，全部亏损问它要'), COLORMAGENTA;
STICKLINE(Var24>0,-3,-9,1,0), LINETHICK3 , COLORRED;
STICKLINE(Var25>0,101,105,1,0),LINETHICK2 , COLORGREEN;
DRAWTEXT(发现>0,25,'短线黑马2.5%') , COLORCC99FF;
DRAWTEXT(黑马>0,52,'黑马发现10%' ), COLORYELLOW;
DRAWTEXT(大黑马,70,'★大方日线专用大黑马获利10%以上'),LINETHICK2 , COLORRED;
0,LINETHICK1,COLORFF9966;
100  , COLORFF9966;

引用:

大智慧的原码如下:

Var3:=EMA(100*(CLOSE-LLV(LOW,100))/(HHV(HIGH,100)-LLV(LOW,100)),5);
Var4:=(CLOSE-LLV(CLOSE,N))/(HHV(CLOSE,N)-LLV(CLOSE,N))*100;
Var5:=EMA(CLOSE,2)-EMA(CLOSE,150);
Var6:=EMA(Var5,100);
Var7:=2*(Var5-Var6);
Var8:=POW(Var7,3)*0.1+POW(Var7,1);
Var9:=SQRT(SQRT(LOW*HIGH*OPEN*CLOSE));
VarA:=EMA(Var9*0.97,3);
VarB:=(HIGH+LOW+CLOSE)/3;
VarC:=(VarB-MA(VarB,14))/(0.015*AVEDEV(VarB,14));
黑马线: IF(YEAR<2008 AND Var7>0.1,Var8,0)*5,STICK ,LINETHICK3 ,COLOR0099CC;
VarD:=LLV(HIGH,240);
VarE:=100*(CLOSE-VarD)/VarD;
VarF:=AMOUNT/VOL;
Var10:=EMA((WINNER(CLOSE*1.1)-WINNER(CLOSE*0.9))*80,5);
Var11:=INDEXC;
Var12:=MA(Var11,5);
Var13:=MA(Var11,20);
Var14:=MA(Var11,30);
Var15:=Var14>Var12*1.08 AND Var13>Var12*1.055;
Var16:=Var12>Var11*1.03 AND Var13>Var11*1.13;
Var17:=Var16;
Var18:=IF(FILTER(Var10<6,5)=1,1,0);
发现: (Var18 AND VarE<-2.5 AND Var3<5 AND Var4=0)*60,STICK, COLORff00ff;
Var19:=Var10<6 AND Var17;
黑马: IF(FILTER(Var19,1)=1,1,0)*80,STICK ,  COLORFF6666;
大黑马:if( Var19 AND Var18*80,80,0),LINETHICK2, COLORFF9966;
操盘手: Var4,COLORGRAY;
Var1A:=CROSS(黑马线,2);
Var1B:=CROSS(黑马线,4);
庄拉: IF(FILTER((Var1A OR Var1B) AND Var4<40 AND Var3<40,5)=1,35,0), COLORRED;
Var1C:=(CLOSE-MA(CLOSE,6))/MA(CLOSE,6)*100;
Var1D:=(CLOSE-MA(CLOSE,12))/MA(CLOSE,12)*100;
Var1E:=(CLOSE-MA(CLOSE,24))/MA(CLOSE,24)*100;
Var1F:=REF(CLOSE,1);
Var20:=SMA(MAX(CLOSE-Var1F,0),5,1)/SMA(ABS(CLOSE-Var1F),5,1)*100;
Var21:=(HIGH+LOW+CLOSE)/3;
Var22:=(Var21-MA(Var21,14))/(0.015*AVEDEV(Var21,14));
Var23:(Var1C>=-15.8 AND Var1C<=-12.2 AND Var1D<=-20.8 AND Var1E<=-27.5 AND Var20<=11.7
AND Var22<=-145)*100;
Var24:=Var4;
Var25:=Var4=100;
STICKLINE(Var23>0,90,100,5,0), LINETHICK3 , COLORRED;
DRAWTEXT(Var23>0,90,'发现大黑马加把安全锁，全部亏损问它要'), COLORff00ff;
STICKLINE(Var24>0,-3,-9,1,0), LINETHICK3 , COLORRED;
STICKLINE(Var25>0,101,105,1,0),LINETHICK2 , COLORGREEN;
DRAWTEXT(发现>0,25,'短线黑马2.5%') , COLORCC99FF;
DRAWTEXT(黑马>0,52,'黑马发现10%' ), COLORYELLOW;
DRAWTEXT(大黑马,70,'★大方日线专用大黑马获利10%以上'),LINETHICK2 , COLORRED;
0,LINETHICK1,COLORFF9966;
100  , COLORFF9966;

[ 本帖最后由 蓝鼠 于 2008-2-28 13:06 编辑 ]

引用:

公式名称: 游刃有余
适用软件: 分析家
发 表 人: 福如泉涌     
发表日期: 2006-01-10
发表网址: http://www.chcj.net/viewthread.php?tid=372599&highlight=

引用:

游刃有余-----有助于您纵横股市而游刃有余.



今天发一个自创指标"游刃有余".

该指标有明确的短线买卖指示,能比较个股和大盘的强弱,还能进行波段操作.它有助于您纵横股市而游刃有余.

我在论坛上发的指标不多(但发的多是原创帖),一方面是因为水平有限,另一方面是因为我发的指标,有的热心人在第一时间就贴到别的论坛上去了,这就抑制了我的发贴积极性.

为防止类似事情再次发生,我将在几天之后,视情况再发原码.需要的朋友请在跟帖中说明.此举实属出于无奈,务请朋友们鉴谅.
清晨献上原码,祝朋友们新年大发!

Var2:=llv(low,3)<=llv(low,n);
Var3:=  c>o and (c/o>m or c>m*ref(C,1));
绝地反击:if(Var2 and Var3,20,0),colorred,linethick2;
Var4:=hhv(high,3)>=hhv(high,Q);
Var5:=c<o and (c/o<0.95 or c<p*ref(c,1));
落袋为安:if(Var4 and Var5,80,100),colorgreen,linethick2;
{HURSI}
Var1:=REF(CLOSE,1);
Var22:=REF(INDEXC,1);
Grsi:SMA(MAX(CLOSE-Var1,0),20,1)/SMA(ABS(CLOSE-Var1),20,1)*100;
Drsi:SMA(MAX(INDEXC-Var22,0),20,1)/SMA(ABS(INDEXC-Var22),20,1)*100,coloryellow;
80,colorgreen,pointdot;
50,colorred,pointdot;
20,color0066ff,pointdot;
DY1:=(2*CLOSE+HIGH+LOW)/4;
DY2:=LLV(LOW,34);
DY3:=HHV(HIGH,34);
A1:EMA((DY1-DY2)/(DY3-DY2)*100,9);
B1:EMA((0.667*REF(A1,1)+0.333*A1),2),COLORGREEN;
STICKLINE(A1>=B1,B1,A1,5,0),COLORRED;
STICKLINE(A1<B1,B1,A1,5,0),COLORGREEN;

[ 本帖最后由 蓝鼠 于 2008-2-28 13:11 编辑 ]

引用:

公式名称: 涨停前后
适用软件: 分析家
发 表 人: 福如泉涌     
发表日期: 2006-09-01
发表网址: http://www.chcj.net/viewthread.php?tid=511755&highlight=

引用:

抓住涨停提供的暴利机会-------涨停前后



专做强势股是使自己炒股收益超过大盘的一个好方法.

涨停股是强势股之王.

本指标名为"涨停前后",顾名思义是为捕捉"涨停板"提供的短线暴利机会而制作的.
本指标的"预涨停线","抓涨停线"为股价可能涨停的信号,"拐点"为可介入的短期底部信号,如果在股价运行周期的中低位出现"短线切入"信号,则股价很可能会出现一波凌厉攻势,而"涨停出击"则是在涨停个股中指示可在当日排队抢购或在次日逢低介入的股票.

因此,本指标的信号可分成下面三部分:
1."拐点","预涨停线"为有可能伏击到涨停股票的信号,当然,仅仅是"可能"而已!
2."抓涨停线"和"短线切入"则可用来在当天涨幅排行榜上的涨幅靠前有可能涨停的股票中选择合适的股票介入.
3."涨停出击"信号出现表明该涨停股可在当日排队买如或在次日逢低买进.

下面为指标原码:

Var11:=WINNER(CLOSE)*90;
K: SMA(Var11,3,1);
D: SMA(K,3,1);
J: 3*K-2*D;
江鸟: K>D AND J>K AND CLOSE>REF(CLOSE,1)*1.09 AND MA(VOL,10)>MA(VOL,45) AND VOL>MA(VOL,45);
DRAWTEXT(江鸟,J,'<----涨停出击(10-5%-79%)\');

预涨停线:15,colorff00ff;
抓涨停线:20,colorred;
a:10*vol/ma(vol,n),colorgreen ;
stickline(cross(a,预涨停线),0,100,0.8,0),coloryellow;
stickline(cross(a,抓涨停线),0,100,0.8,0)colorred;

Var1:=ma(c,5);
Var2:=ma(c,24);
穿头破脚:=backset(REF(CLOSE,1)/REF(OPEN,1)<0.97 and close/open>1.04 AND CLOSE>REF(OPEN,1) AND OPEN< REF(CLOSE,1),3) ;
早晨之星:=backset(REF(CLOSE,2)/REF(OPEN,2) < 0.95 AND REF(OPEN,1) < REF(CLOSE,2) AND ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.03 AND
CLOSE/OPEN>1.05 AND CLOSE>REF(CLOSE,2),3) ;
早晨十字星:=backset(REF(CLOSE,2)/REF(OPEN,2) < 0.95 AND REF(OPEN,1) < REF(CLOSE,2) AND REF(OPEN,1)=REF(CLOSE,1) AND CLOSE/OPEN>1.05 AND CLOSE>REF(CLOSE,2),3);
平底:=backset((ABS(LOW-REF(LOW,1))/LOW<0.001 AND ABS(REF(LOW,1)-REF(LOW,2))/REF(LOW,1)<=0.001),3) ;
曙光初现:=backset(REF(CLOSE,1)/REF(OPEN,1)<0.97 AND CLOSE/OPEN>1.03 AND OPEN< REF(CLOSE,1) AND CLOSE>REF(CLOSE,1),3);
跳空缺口:= backset(LOW>REF(HIGH,1),3);
长下影:=(MIN(CLOSE,OPEN)-LOW)/(HIGH-LOW)>0.667 ;
预警:=穿头破脚 or 早晨之星 or 早晨十字星 or 平底 or 曙光初现  or 长下影 or 跳空缺口;
Var3:count(预警 ,5) >=1;


短线切入: if(cross(c,Var2)and C/ref(c,1)>1.095  and Var3 and 100*v/capital<10,120,0) ,colorred linethick2;
Var4:=Var1/ref(Var1,1);
Var5:=Var2/ref(var2,1);
拐点:if(Var3  and cross(Var4,1)  and ma(v,5)>ma(v,10) ,100,0),colorgreen ;
55;
90;
0;

n  10  1   100
再发一张图,供参考:

[ 本帖最后由 蓝鼠 于 2008-2-28 13:19 编辑 ]

引用:

公式名称: 均线速度
适用软件: 分析家
发 表 人: 福如泉涌     
发表日期: 2006-12-09
发表网址: http://www.chcj.net/viewthread.p ... ghlight=&page==

引用:

均线,均线速度及公式



股价移动平均线(后文简称为均线)是助研究股价走势的最有效,最常用的工具之一.
可以毫不夸张地说,每个股市投资者,在对股市进行研判,或进行买卖的实际操作时,无不需要借助均线(系统).
俗语说得好:工欲善其事,必先利其器.我们要想在股市中长久生存,甚至稳定获利,就必须学习,研究进而熟练掌握我们所使用的工具-----均线,让其更好地为我们的投资服务.

一,均线MA原理及其计算
用最简明的表述来定义均线就是:
某周期内的平均收盘价.亦即:
MA(n)=sum(close,n)/n;    或:
MA(n):MA(close,n);

二,均线的特点与作用
1,周期
均线的周期就是股票软件中所设定的时间周期.如日线图中的5日,10日,20日,30日等,在周,月线图中可依此类推.我们也可以按自己个人的喜好或习惯设定周期.
一般而言,短期均线应设在20天以下,中期为20到100天,100天以上为长期均线.
2,特点与作用
(1),时滞性
由于均线是多日股价的平均值,所以均线的变动必然滞后于股价的变动.均线周期越长,越是不易上下波动.从而能有效地过滤掉日常的骗线. 但也为我们捕捉抄底及逃顶的最佳时机带来了困难.  
(2),代表市场目前的平均持股成本
如5日均线表示在5天中股民买入股票的平均价格,股价上穿5日均线,表明股民原意以高于市场5日平均价买入股票,反映市场看好这只股票,后市看涨.反之亦然.
如股价因急剧上涨,而远远高于5日均价,市场上的持股者多数都多是获利的,就会有获利了结的要求,后市向下的可能就大.
所以我们可以用均线的这个特性来预判股价后市的走势.
(3),助涨助跌作用
当股价上涨过快,远离短期均线时,因正乖离过大,股价将向短期均线回归.在均线附近,因股价与短期持股成本相近,获利盘几乎没有,因而抛压极轻.在大盘条件向好的环境下,在短期均线附近,就又有买方力量介入,从而把股价再次拉起.由于此时均线是向上运行的,从宏观看,仿佛是股价一回落到均线,就被均线"弹"了起来.这就是均线的助涨作用.
反之,均线的助跌作用,也可依此类推.
我们可以运用这个原理,当股价在上升通道运行时,回档到均线附近介入,而不必追高,以免短线被套.
同理,当股价在下降通道运行时,反弹到均线附近高抛,以免再次深套.
(4)趋势的指向作用
这也许是均线的最主要的作用.
当均线的趋势一旦形成,往往会沿着这一趋势继续运行一段时间.从而使均线有预判股价后市走向的作用,即均线有趋势的指向作用.
当均线向上运行时,只要它的趋势没有改变,就应该继续持股.
当均线向下运行时,只要它的趋势没有改变,就应该继续持币.
只有在均线转折时,才是我们进行操作的最佳时机.
三,均线运行的速度
很多技术分析的书籍在谈到均线时,只是笼统地谈到,均线向上(下)角度越大,股价上涨(下跌)越厉害.对均线运行的速度没有提及,这不能不是个缺憾.
1.为什么要研究均线运行的速度?
我们在上文提到:
当均线向上运行时,只要它的趋势没有改变,就应该继续持股.
当均线向下运行时,只要它的趋势没有改变,就应该继续持币.
只有在均线转折时,才是我们进行操作的最佳时机.
我们知道,当均线向上运行时,随着股价的不断上涨,获利盘的增加,做多动能在不断衰竭,均线向上运行的速度也在随之减慢,当均线向上运行的速度变为零时,均线就拐头下行,而均线向上运行的速度变为零这一点位,正是我们所要求取的,因为这一点位也正是均线的拐点.
所以,我们研究均线运行的速度,目的就在于求得均线运行的拐点,从而找到科学的最佳的操作时机.
2.均线运行的速度
为了叙述方便,我们以5日均线为例.
我们知道,5日均线其实就是每天的5日均线值的运行轨迹.如果把每天的5日均线值看成是一个质点,则5日均线也就是这些质点的运行轨迹.我们只要求出某一时间质点的运行速度,也就知道5日均线在该天的速度了!
这样,我们就可以用物理学的方法来求取均线运行的速度
对匀速运动的质点来说,速度等于距离除以时间.即:
V=S/T
对非匀速运动的质点来说,某一时间的速度等于距离对于时间的导数.即:
V=dS/dt
  =(S1-S0)/(T1-T0)
若令(T1-T0)为一单位时间,则S1-S0就是该单位时间的速度.
设MA5=S1,即当天的5日均价,前一天的5日均价ref(MA5,1)=S0,那么
5日均线在当天的速度近似为:
MA5-ref(MA5,1).
四.公式及说明
1,公式:
下面发根据这一思路所编写的公式,名称就叫:"均线速度"吧!
input:P1(1,20,5)      P2(1,60,30)
A1:=MA(CLOSE,P1);A2:=REF(A1,1);J1:(A1-A2)/A2*100;MJ1:ma(J1,3);
A3:=MA(CLOSE,P2);A4:=REF(A3,1);J2:(A3-A4)/A4*100;MJ2:=MA(J2,10);
A5:=ma(c,10);A6:=ref(A5,1);
J3:=(A5-A6)/A6*100;Mj3:=ma(j3,5);
{向上拐点:if(count(cross(j1,0),3)>=1 and mj1>mj3 and mj3>ref(mj3,1) and J3>=0 and J1>ref(j1,1),5,0) ,colorred,linethick2;
向下拐点:if(cross(0,j1)>=1 and mJ3<ref(mj3,1) and mJ2<ref(mj2,2) and mJ3<mJ2,-5,0),colorgreen,linethick2;}
0,COLORwhite;
STICKLINE(J1>0 AND J2>0,J1,0,2,0),COLORRED;
STICKLINE(J1<0 AND J2>0,0,J1,2,0),COLORYELLOW;
STICKLINE(J1>0 AND J2<0,J1,0,2,0),COLORMAGENTA;
STICKLINE(J1<0 AND J2<0,0,J1,2,0),COLORGREEN;
DRAWICON(CROSS(J1,mJ1) AND count(mj1<-3,3)>=1 ,J1*1.5,1);
DRAWICON(CROSS(mJ1,J1) AND count(mj1>3,3)>=1,J1*1.8,2);
选股:if(CROSS(J1,mJ1) AND  count(mj1<-2,3)>=1,2,0),coloryellow,linethick2;
B1:=BARSLAST(REF(CROSS(J1,MJ1) and MJ1<0,1));
底背离:=REF(CLOSE,B1+1)>CLOSE AND J1>REF(J1,B1+1) AND CROSS(J1,MJ1);
DRAWLINE(B1=0,MJ1,底背离,MJ1,0),COLORRED,linethick3;
B2:=BARSLAST(REF(CROSS(MJ1,J1) and MJ2>0,1));
顶背离:=REF(CLOSE,B2+1)<CLOSE AND REF(MJ1,B2+1)>J1 AND CROSS(MJ1,J1);
DRAWLINE(B2=0,MJ1,顶背离,MJ1,0),COLORWHITE,linethick2;

引用:

大智慧L-2


A1:=MA(CLOSE,P1);
A2:=REF(A1,1);
J1:(A1-A2)/A2*100;
MJ1:ma(J1,3);
A3:=MA(CLOSE,P2);
A4:=REF(A3,1);
J2:(A3-A4)/A4*100;
MJ2:=MA(J2,10);
A5:=ma(c,10);
A6:=ref(A5,1);
J3:=(A5-A6)/A6*100;
Mj3:=ma(j3,5);
{向上拐点:if(count(cross(j1,0),3)>=1 and mj1>mj3 and mj3>ref(mj3,1) and J3>=0 and J1>ref(j1,1),5,0) ,colorred,linethick2;
向下拐点:if(cross(0,j1)>=1 and mJ3<ref(mj3,1) and mJ2<ref(mj2,2) and mJ3<mJ2,-5,0),colorgreen,linethick2;}
0,COLORwhite;
STICKLINE(J1>0 AND J2>0,J1,0,2,0),COLORRED;
STICKLINE(J1<0 AND J2>0,0,J1,2,0),COLORYELLOW;
STICKLINE(J1>0 AND J2<0,J1,0,2,0),COLORMAGENTA;
STICKLINE(J1<0 AND J2<0,0,J1,2,0),COLORGREEN;
DRAWICON(CROSS(J1,mJ1) AND count(mj1<-1,3)>=1 ,J1*1.5,1);
DRAWICON(CROSS(mJ1,J1) AND count(mj1>1,3)>=1,J1*1.8,2);

引用:

2.使用说明
(1)J1下穿0轴,表示5日均线向下拐头.反之,
J1上穿0轴,表示5日均线向上拐头.
(2)J2J1下穿0轴,表示30日均线向下拐头.反之,
J2上穿0轴,表示30日均线向上拐头.
(3)当J1在1以上死叉MJ1时,警惕头部来临.为卖出信号.
当J1在-1以下金死叉MJ1时,注意底部来临.为买入信号.
(4)本指标配合"短线操盘"指标使用,效果较好.

[ 本帖最后由 蓝鼠 于 2008-2-28 13:30 编辑 ]

引用:

公式名称: 波动突破
适用软件: 分析家
发 表 人: 福如泉涌     
发表日期: 2007-09-24
发表网址: http://www.chcj.net/viewthread.php?tid=847295&highlight=

引用:

迎国庆,庆中秋,奉送新编指标------波动突破



祝创幻指标区的朋友们,
中秋,国庆佳节快乐!




现奉上我新编的主图指标---波动突破,希望大家喜欢!

先发原码:

MA5:MA(CLOSE,5);
ma10:ma(c,10);
MA20:MA(CLOSE,20);
MA30:MA(CLOSE,30);
ma60:ma(c,60);
MA120:MA(CLOSE,120);
MA250:MA(CLOSE,250),colorred;
stickline(c>1.099*ref(c,1),o,c,8,0),coloryellow;
stickline(c>1.099*ref(c,1),o,c,8,0),coloryellow;
火车轨:=MA20>MA30 and MA20>ref(MA20,1) and MA30>ref(MA30,1) and ma20-ma30>ref(ma20-ma30,1);
stickline(火车轨,ma20,ma30,1,0),coloryellow;
{波动性突破}
Var1:=(h-l)/l*100;
Var2:=ref(Var1,1) ;
Var3:=ref(Var1,2);
Var4:=Var2-Var3;
var5:=Var2+Var4;
drawtext((c/ref(c,1)-1)>Var5 and ma20>ref(ma20,1) and C>O,l*0.95,'←波动突破'),colorred;
{金印组合}
QH:=REF(H,2);
QL:=REF(L,2);
QO:=REF(O,2);
QC:=REF(C,2);
ZO:=REF(O,1);
ZC:=REF(C,1);
JYZHK:= ABS(QO-QC)/QO<0.02 AND ZO/ZC>1.03  AND ABS(O-C)/O<0.02 AND C>MA(C,30);
JYZHV:=V<REF(V,1) ;
JYZH:=JYZHK AND JYZHV;
DRAWTEXT(JYZH,L,'←金印');
{金冠组合}
JGZHK:=ABS(QO-QC)/QO<0.02 AND ZC/ZO>1.05  AND ABS(O-C)/O<0.02 AND C>MA(C,30);
JGZHV:=ref(V,1)>=2*ref(V,2);
JGZH:=JGZHK and JGZHV;
DRAWTEXT(JGZH,H*1.02,'←金冠'),coloryellow;
波动突破选股:=(c/ref(c,1)-1)>Var5 and ma20>ref(ma20,1) and c>o;

[ 本帖最后由 蓝鼠 于 2008-2-28 13:33 编辑 ]

引用:

公式名称: 福泉神枪
适用软件: 大智慧L2
发 表 人: 福如泉涌     
发表日期: 2007-10-29
发表网址: http://www.chcj.net/viewthread.php?tid=881353&highlight=

引用:

福泉神枪




神枪在手,
炒股不愁!

为答谢各位版主的和广大网友的厚爱,特发大智慧新一代用的主图指标---"福泉神枪",希望朋友们喜欢!

先发原码:


ma5:ma(c,5);;
ma6:=ma(c,6);
ma10:ma(c,10);
ma20:ma(c,20);
A2:=REF(ma20,1);J1:=(ma20-A2)/A2*100;MJ1:=ma(J1,3);
ma30:ma(c,30);
ma55:ma(c,55);
ma120:ma(c,120);
乖离2:=(ma20-ma30)/ma30*100;
Var1:=if(between(乖离2,-2,m),2,0);
max1:=max(ma20,ma30);
max2:=max(max1,ma55);
min1:=min(ma20,ma30);
min2:=min(min1,ma55);
k1:=(max2/min2-1)*100;{粘合度符合条件}
vAR2:=IF(K1<=p,1,0);
上火车轨:=ma20>ma30 and ma20>ref(ma20,1) and ma30>ref(ma30,1) and ma20-ma30>ref((ma20-ma30),1) ;
stickline(上火车轨,ma20,ma30,2,0),colorred;
神枪手:=drawtext(filter(上火车轨  and "macd.diff"<0.15 and "macd.diff">ref("macd.diff",1) and ma(v,60)>ref(ma(v,60),1) and ma(v,5)>ma(v,10) and J1>ref(j1,1) and
(  l<=ma20 and  c>ma20 or (cross(ma5,ma20)) ),5),l*0.98,'←神枪手');
神枪手选股:=filter(上火车轨  and "macd.diff"<0.15 and "macd.diff">ref("macd.diff",1) and ma(v,60)>ref(ma(v,60),1) and ma(v,5)>ma(v,10) and J1>ref(j1,1) and
(  l<=ma20 and  c>ma20 or (cross(ma5,ma20)) ),5);{44.40%15240}
短线暴涨:drawtext(filter( (Var1 or Var2) and ma10>ref(ma10,1) and count(ma30>ref(ma30,1),3)=3 and ma30>ma55   and count(cross(ma5,ma30),3) and J1>MJ1 and ma(v,5)>ma(v,60)
and ma(v,60)>ref(ma(v,60),1),5),ma55*0.9,'短线暴涨'),colorred;
drawtext(cross("kdj.k"(5,2,3),"kdj.d"(5,2,3)) and "kdj.D"(5,2,3)<30 and  j1>mj1 and ma55>ref(ma55,1) and  count(J1<1,3)>=1 ,l*0.995,'←买入'),coloryellow;
drawtext(cross("kdj.d"(5,2,3),"kdj.k"(5,2,3)) and "kdj.D"(5,2,3)>65 and j1<mj1 and count(J1>1,3)>=1,h*1.005,'←卖出'),colorgreen;
drawtext(cross("kdj.d"(18,9,6),"kdj.k"(18,9,6)) and "kdj.d"(18,9,6)>60  and "kdj.j"(45,15,15)>90,h*1.03,'←顶'),colorred;
drawtext(cross(ma5,ma6) and "kdj.k"(5,3,3)>=50 and "kdj.j"(5,3,3)<31 ,l*0.92,'←再买'),colormagenta;
XL1:=((LLV(LOW,3) = LLV(LOW,60)) AND ((CLOSE / REF(CLOSE,1)) >= 1.04));
XL2:=(((CLOSE - EMA(CLOSE,21)) / EMA(CLOSE,21)) * 100);
XL3:=CROSS(XL2,(0 - 20));
DRAWTEXT(FILTER(((XL1 > 0) AND LOW),5),(LOW - 0.4),'●买点');
DRAWTEXT((XL3 > 0),(LOW - 0.2),'●绝对底部');
X6:=REF(CLOSE,1);
X7:=((SMA(MAX((CLOSE - X6),0),7,1) / SMA(ABS((CLOSE - X6)),7,1)) * 100);
X8:=CROSS(79,X7);
X9:=FILTER(X8,4);
DRAWTEXT(X9,(HIGH * 1.02),'●出货'),color9000F5;
stickline(C>1.098*ref(c,1),c,o,8,0),coloryellow;
m=10
p=4

[ 本帖最后由 蓝鼠 于 2008-3-1 08:21 编辑 ]

引用:

公式名称: 绝地反击
适用软件: 其它公式
发 表 人: 福如泉涌     
发表日期: 2005-12-22
发表网址: http://www.chcj.net/viewthread.php?tid=363918&highlight=

引用:

绝地反击



绝地反击

Var2:=llv(low,3)<=llv(low,60);
Var3:=  c>o and (c/o>1.03 or c>1.03*ref(C,1));
绝地反击:if(Var2 and Var3,5,0),colorred,linethick2;

发个图供参考:

引用:

按国际惯例,没人顶,自己先顶一下!

本公式看似简单,但却是按于理义教授的上涨定式编写的.如图所示,它能较为准确地指出波段的买点.

使用本公式的玄机是:

1.和"波段高手",布林线,或薛斯通道等指标一起使用,它能给这些通道指标标明准确的买点.

2.如果将公式稍加改变,使其参数可调,则可大大提高其成功率.如:

Var2:=llv(low,3)<=llv(low,N);
Var3:=  c>o and (c/o>M or c>=M*ref(C,1));
绝地反击:if(Var2 and Var3,5,0),colorred,linethick2;

N可选60,90,120,直至240;
M可选1.03,1.05,1.08,直至涨停.
但是,出现的信号量会因此而降低.如果一年只做两三波行情,参数可设成:N,120   M,1.08.
喜欢做波段的,参数可设成:N,60    M,1.03

[ 本帖最后由 蓝鼠 于 2008-3-1 08:32 编辑 ]

引用:

公式名称: 短线切入
适用软件: 分析家
发 表 人: 福如泉涌     
发表日期: 2006-07-16
发表网址: http://www.chcj.net/viewthread.php?tid=476861&highlight=

引用:

短线切入

短线切入是我新近编写的公式,公式并不复杂,让朋友们见笑了!

一般而言,一只短线暴涨股快速拉升的周期仅为一周时间.因此,寻找短线切入的适当时机对于迅速获利就显得十分重要.
见到短线切入的买入信号,在设好止损位的前提下,次日逢低介入,持股一周左右,逢高抛出,常会有不错的收益(当然要有良好的大盘环境的配合).之后在寻找下一个目标股只.

先发指标原码:
以下内容需要积分高于 2 才可浏览
Var1:=ma(c,24);
穿头破脚:=REF(CLOSE,1)/REF(OPEN,1)<0.97 and close/open>1.04 AND CLOSE>REF(OPEN,1) AND OPEN< REF(CLOSE,1) ;
早晨之星:=REF(CLOSE,2)/REF(OPEN,2) < 0.95 AND REF(OPEN,1) < REF(CLOSE,2) AND ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.03 AND
CLOSE/OPEN>1.05 AND CLOSE>REF(CLOSE,2) ;
早晨十字星:=REF(CLOSE,2)/REF(OPEN,2) < 0.95 AND REF(OPEN,1) < REF(CLOSE,2) AND REF(OPEN,1)=REF(CLOSE,1) AND CLOSE/OPEN>1.05 AND CLOSE>REF(CLOSE,2);
平底:=(ABS(LOW-REF(LOW,1))/LOW<0.001 AND ABS(REF(LOW,1)-REF(LOW,2))/REF(LOW,1)<=0.001) ;
曙光初现:=REF(CLOSE,1)/REF(OPEN,1)<0.97 AND CLOSE/OPEN>1.03 AND OPEN< REF(CLOSE,1) AND CLOSE>REF(CLOSE,1);
跳空缺口:= LOW>REF(HIGH,1);
Var3:=count((穿头破脚 or 早晨之星 or 早晨十字星 or 平底 or 曙光初现 or 跳空缺口) ,5) >=1;
短线切入: cross(c,Var1)and C/ref(c,1)>1.095  and Var3 ;
{1.ma24应在低位;
2.在涨停买入信号出现之前应有见底组合K线}





再发一张图,供参考:

[ 本帖最后由 蓝鼠 于 2008-3-1 08:38 编辑 ]

引用:

公式名称: 刀剑合璧
适用软件: 分析家
发 表 人: 福如泉涌     
发表日期: 2008-02-24
发表网址: http://www.chcj.net/viewthread.php?tid=1000665&highlight=

引用:

刀剑合璧-----蓝鼠兄荣任指标区版主志庆





刀剑合璧





   为庆贺好友蓝鼠兄荣任指标区版主之职,特发新编指标"刀剑合璧",祝蓝鼠兄在指标区一展雄风,尽显才华!
      
       呵呵,
       屠龙刀,伏魔剑,
       刀剑合璧,
       威力无比!
       驰骋股市,
       无往不利!

    下面先发原码:

RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100;
K:SMA(RSV,M1,1);
D:SMA(K,M2,1);
J:3*K-2*D;

Var1:="kdj.j#week",color0099cc,linethick2;
伏魔剑:=Var1<=15 and Var1-ref(Var1,5)<=5;
屠龙刀:= Var1>80   and  Var1-ref(Var1,6)>=-10;
Var3:=(c+h+l+o)/4;
Var4:=llv(l,34);
Var5:=hhv(h,34);
Var6:=ema((Var3-Var4)/(Var5-Var4)*100,8);
Var7:ema(Var6,5);
stickline((Var6-Var7)>0,Var6,Var7,10,1),colorred;
stickline((Var6-Var7)<0,Var6,Var7,10,1),colorcyan;
stickline( 屠龙刀 ,110,120,10,0),colorred;
stickline( 伏魔剑,-20,-10,10,0),colorgreen;
参数:N  9 1  100
    M1 3  1  100
    M2 3  1  100

引用:

指标用法:
KDJ是我最喜爱的指标之一,但其缺点却也十分明显.那就是在高位和低位容易出现钝化.这时进行交易,容易踏空或套牢,从而使人无所适从.为了解决这个问题,我编写了这个指标,把我在实战中使用的心得浓缩在这个公式中.
1.屠龙刀高悬,KDJ死叉,也不是卖点,只有在屠龙刀红柱消失,才可按KDJ死叉信号卖出.
2.有伏魔剑信号时,即使KDJ金叉,也不能买入,等待伏魔剑信号消失,才可按KDJ金叉信号买入.
从而避免了因在KDJ高位死叉抛出股票后不久股价却飞涨而引起的踏空之痛,
也可免受因在KDJ低位金叉买入股票后不久股价却持续下跌而导致的套牢之苦!

[ 本帖最后由 蓝鼠 于 2008-3-1 08:45 编辑 ]

引用:

公式名称: 精准买卖
适用软件: 大智慧L2
发 表 人: 福如泉涌     
发表日期: 2008-05-05
发表网址: http://www.li20.net/thread-1081641-1-3.html

引用:

精准买卖





昨天上网,看到jxdxlh002君发的"掌握一天的买卖精确点",觉得很是不错.(见:http://www.chcj.net/thread-1080051-1-2.html)

不错在哪?在于有原码,有图.

这样的帖子,不顶,不加分,似乎对不起帖主.于是我既顶又加分,以表达我对jxdxlh002君的感谢之情.

只是稍有遗憾,正如dave928君在跟帖中指出的:很好的指标，看了一下，只显示买入股票，怎么不显示见顶清仓。

为了解决这个问题,我下载了该指标,并按我的理解做了修改.我将修改后的指标原码公布在下面.

公布指标原码的目的是为了互相交流,共同提高.如果有高手将这个指标作进一步的优化,那就再好不过了!

原码如下:


V1:=(C*2+H+L)/4*10;
V2:=EMA(V1,13)-EMA(V1,34);
V3:=EMA(V2,5); V4:=2*(V2-V3)*5.5;
主力撤: IF(V4<=0,V4,0),colorblue;
主力进: IF(V4>=0,V4,0),colorff00ff;
V5:=(HHV(INDEXH,8)-INDEXC)/(HHV(INDEXH,8)-LLV(INDEXL,8))*8;
V6:=EMA(3*V5-2*SMA(V5,18,1),5);
V7:=(INDEXC-LLV(INDEXL,8))/(HHV(INDEXH,8)-LLV(INDEXL,8))*10;
V8:=(INDEXC*2+INDEXH+INDEXL)/4;
V9:=EMA(V8,13)-EMA(V8,34);
VA:=EMA(V9,3);
VB:=(V9-VA)/2;
大盘资金进场:IF(VB>=0,VB,0),Colorred;
大盘资金撤走:IF(VB<=0,VB,0),colorgreen;
V11:=3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA(SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1),3,1);
趋势线: EMA(V11,3);
V12:=(趋势线-REF(趋势线,1))/REF(趋势线,1)*100;
准备现金: STICKLINE(趋势线<=13,0,20,5,0),colorcc9900;
aa:=(趋势线<=13) and filter((趋势线<=13),15);
drawtext (aa,30,'准备现金'),colorcc9900;
买入股票: STICKLINE(趋势线<=13 AND V12>13,0,50,5,0),color0099ff;
bb:= (趋势线<=13 AND V12>13) and filter((趋势线<=13 AND V12>13),10) ;
drawtext (bb,60,'买入股票'),color0099ff;
卖临界: STICKLINE(趋势线>90 and 趋势线>ref(趋势线,1),100,95,15,1),COLORFFFF00;
见顶清仓:filter(趋势线>90 and 趋势线<ref(趋势线,1) and 主力进<ref(主力进,1),8);
DRAWTEXT( 见顶清仓,90,'逃顶'),coloryellow;
cc:=(趋势线>=90 AND V12) and filter((趋势线>=90 AND V12),10);
stickline(大盘资金进场  and 趋势线<13,0,30,10,0),colorred;
stickline(大盘资金撤走  and 趋势线>90,0,30,10,0),colorgreen;
stickline(主力进 and 趋势线<13,0,40,10,0),colorff00ff;
stickline(主力撤 and 趋势线>90,0,40,10,0),colorblue;

要说明的是,本指标不仅分时可用,各个周期都可以用.
当然,指标不是万能的.炒股的经验才是决胜股市的关键.
如果觉得好,就请费心顶一下!谢谢先!

[ 本帖最后由 蓝鼠 于 2008-5-12 08:29 编辑 ]

引用:

公式名称: 青云直上
适用软件: 大智慧L2
发 表 人: 福如泉涌     
发表日期: 2008-07-01
发表网址: http://www.li20.net/thread-1136718-1-1.html

引用:

有了"短线操盘指标------青云直上",股市就是你的提款机!
为了庆祝党的生日,并答谢版主们和广大网友对我的帮助和支持,特发原创指标-------青云直上,如果觉得还有使用价值,烦请顶一下,以让更多的朋友们看到.

    您的举手之劳,对我是莫大的鼓励!

    下面先发原码:

     DRAWGBKLAST(CLOSE>0,STRIP(RGB(95,95,95),RGB(0,0,0),0));
AA05:MA(C,5),color0099cc;
五日乖离率:=(c-AA05)/AA05*100;
BB05:=atan((aa05/ref(aa05,1)-1)*100)*180/3.1416;
速度5:=sma(ema((AA05-ref(AA05,1))/ref(AA05,1),3)*100,3,1);
加速度5:ema((速度5-ref(速度5,1)),3),linethick0;
STICKLINE(BB05>30 and AA05>ref(AA05,1), AA05,REF(AA05,1),8,1),colorcyan;
AA10:MA(C,10);AA20:=MA(c,20);
BB10:=atan((aa10/ref(aa10,1)-1)*100)*180/3.1416;
STICKLINE(BB05<0 and AA05<ref(AA05,1), AA05,REF(AA05,1),8,1),coloryellow;
AA30:MA(C,30);
三拾日乖离率:(c-AA30)/AA30*100,linethick0;
Var1:=(AA20-AA30)>ref((AA20-AA30),1) and AA20>ref(aa20,1) and AA30>ref(AA30,1);
Var2:=(AA30-AA20)<ref((AA30-AA20),1) and AA20<ref(aa20,1) and AA30<ref(AA30,1);
BB30:=atan((aa30/ref(aa30,1)-1)*100)*180/3.1416;
STICKLINE(BB30>15 and AA30>ref(AA30,1), AA30,REF(AA30,1),8,1),colorff00ff;
强势狙击:=filter(BB30>30 and BB10>45 and cross(BB05,60),10);
加仓:=filter(count(cross(BB05,30),5)>=1 and AA05>ref(aa05,1)  and 三拾日乖离率>ref(三拾日乖离率,1) and AA10>ref(AA10,1)
and 加速度5>ref(加速度5,1) and 速度5>ref(速度5,1)  ,10) ;
清仓:=filter(count(cross(30,BB05),5)>=1 and (c>AA30 or O>AA30) and AA05<ref(aa05,1)  and 三拾日乖离率<ref(三拾日乖离率,1) and AA10<ref(AA10,1),10);
drawtext(加仓 ,low*0.98,'←加仓'),colorred;
JC:=cross(0,五日乖离率) and 三拾日乖离率<ref(三拾日乖离率,1) and AA10>ref(AA10,1) ;
减仓:=filter(JC,10);
MR:=count(cross(五日乖离率,0),3)>=1 and 三拾日乖离率>ref(三拾日乖离率,1) and AA05>ref(AA05,1) and (c/ref(c,1)-1)*100>5 and ref(c,1)<AA30;
买入:=filter(MR,10);
drawtext(减仓,high*1.02,'←减仓'),colorcyan;
drawtext(买入,low*0.98,'←买入'),coloryellow;
drawtext(清仓 ,high*1.02,'←清仓'),colorgreen;
drawtext(强势狙击,LOW*0.98,'←强势狙击'),coloryellow;
Var21:=MAX(ABS(HIGH-AMOUNT/VOL/100),ABS(AMOUNT/VOL/100-LOW));
Var3:=ABS((OPEN+CLOSE)/2-AMOUNT/VOL/100);
MV:=(Var21+Var3)/AMOUNT*VOL*100*50;
DRAWTEXT(MV>6 and l<=llv(l,10),l*0.95,'←异动'),colorcyan;